EOPL 第3章の Exercise 3.29 [Lisp]
練習問題 3.29 は proc と同様だけど入口と出口でトレースメッセージを表示する traceproc を追加する。特にどうということはない問題。
; Exercise 3.29
(load "r5rs.scm")
(load "define-datatype.scm")
(load "sllgen.scm")
(load "./2.eopl.scm") ; for extend-env, empty-env
(define true-value (lambda () 1))
(define false-value (lambda () 0))
(define true-value?
(lambda (x)
(not (= 0 x))))
(define closure
(lambda (ids body env)
(lambda (args)
(if (= (length ids) (length args))
(eval-expression body (extend-env ids args env))
(eopl:error 'closure
"Wrong number of arguments: ~s required, but got ~s"
(length ids) (length args))))))
(define eval-program
(lambda (pgm)
(cases program pgm
(a-program (body)
(eval-expression body (init-env))))))
(define eval-expression
(lambda (exp env)
(cases expression exp
(lit-exp (datum) datum)
(var-exp (id) (apply-env env id))
(primapp-exp (prim rands)
(let ((args (eval-rands rands env)))
(apply-primitive prim args)))
(if-exp (test-exp true-exp false-exp)
(if (true-value? (eval-expression test-exp env))
(eval-expression true-exp env)
(eval-expression false-exp env)))
(let-exp (ids rands body)
(let ((args (eval-rands rands env)))
(eval-expression body (extend-env ids args env))))
(proc-exp (ids body)
(closure ids body env))
(traceproc-exp (ids body)
(let ((proc (closure ids body env)))
(lambda (args)
(display (format "enter: ~s\n" args))
(let ((result (proc args)))
(display (format "exit: ~s\n" result))
result))))
(app-exp (rator rands)
(let ((proc (eval-expression rator env))
(args (eval-rands rands env)))
(apply-procval proc args)))
)))
(define eval-rands
(lambda (rands env)
(map (lambda (x) (eval-rand x env)) rands)))
(define eval-rand
(lambda (rand env)
(eval-expression rand env)))
(define apply-primitive
(lambda (prim args)
(cases primitive prim
(add-prim () (+ (car args) (cadr args)))
(subtract-prim () (- (car args) (cadr args)))
(mult-prim () (* (car args) (cadr args)))
(incr-prim () (+ (car args) 1))
(decr-prim () (- (car args) 1))
)))
(define apply-procval
(lambda (proc args)
(proc args)))
(define init-env
(lambda ()
(extend-env
'(i v x)
'(1 5 10)
(empty-env))))
(define scanner-spec-3.29
'((white-sp
(whitespace) skip)
(comment
("%" (arbno (not #\newline))) skip)
(identifier
(letter (arbno (or letter digit "?"))) symbol)
(number
(digit (arbno digit)) number)))
(define grammar-3.29
'((program
(expression)
a-program)
(expression
(number)
lit-exp)
(expression
(identifier)
var-exp)
(expression
(primitive "(" (separated-list expression ",") ")" )
primapp-exp)
(expression
("if" expression "then" expression "else" expression)
if-exp)
(expression
("let" (arbno identifier "=" expression) "in" expression)
let-exp)
(expression
("proc" "(" (separated-list identifier ",") ")" expression)
proc-exp)
(expression
("traceproc" "(" (separated-list identifier ",") ")" expression)
traceproc-exp)
(expression
("(" expression (arbno expression) ")")
app-exp)
(primitive ("+") add-prim)
(primitive ("-") subtract-prim)
(primitive ("*") mult-prim)
(primitive ("add1") incr-prim)
(primitive ("sub1") decr-prim)
))
(define scan&parse
(sllgen:make-string-parser
scanner-spec-3.29
grammar-3.29))
(sllgen:make-define-datatypes scanner-spec-3.29 grammar-3.29)
(define run
(lambda (string)
(eval-program
(scan&parse string))))
(define read-eval-print
(sllgen:make-rep-loop "-->" eval-program
(sllgen:make-stream-parser
scanner-spec-3.29
grammar-3.29)))
; let makemult = traceproc (maker, x)
; if x
; then +(4, (maker maker -(x, 1)))
; else 0
; in let times4 = traceproc (x) (makemult makemult x)
; in (times4 3)
; -->enter: (3)
; enter: (#<closure (eval-expression eval-expression eval-expression)> 3)
; enter: (#<closure (eval-expression eval-expression eval-expression)> 2)
; enter: (#<closure (eval-expression eval-expression eval-expression)> 1)
; enter: (#<closure (eval-expression eval-expression eval-expression)> 0)
; exit: 0
; exit: 4
; exit: 8
; exit: 12
; exit: 12
; 12
コメント 0