EOPL 第3章の Exercise 3.26

前回と同じく環境から名前を取りさる処理をフラットな環境（単なるリスト）で行う。これでレキシカルアドレスはただの整数に単純化された。

; Exercise 3.26
(load "r5rs.scm")
(load "define-datatype.scm")
(load "sllgen.scm")

(define empty-env
  (lambda () '()))

(define extend-env
  (lambda (vals env)
      (append vals env)))

(define apply-env
  (lambda (env pos)
    (list-ref env pos)))

(define true-value (lambda () 1))
(define false-value (lambda () 0))
(define true-value?
  (lambda (x)
    (not (= 0 x))))

(define closure
  (lambda (ids body env)
    (lambda (args)
      (if (= (length ids) (length args))
        (eval-expression body (extend-env args env))
        (eopl:error 'closure
                    "Wrong number of arguments: ~s required, but got ~s"
                    (length ids) (length args))))))

(define lexical-address
  (lambda (pgm)
    (letrec
      ((la
         (lambda (exp bs)
           (cases expression exp
             (lit-exp (datum) exp)
             (var-exp (id) (lexvar-exp (get-pos id bs)))
             (lexvar-exp (pos) exp)
             (primapp-exp (prim rands)
               (primapp-exp prim (map (lambda (x) (la x bs)) rands)))
             (if-exp (test-exp true-exp false-exp)
               (if-exp (la test-exp bs) (la true-exp bs) (la false-exp bs)))
             (let-exp (ids rands body)
               (let-exp ids
                        (map (lambda (x) (la x bs)) rands)
                        (la body (append ids bs))))
             (proc-exp (ids body)
               (proc-exp ids (la body (append ids bs))))
             (app-exp (rator rands)
               (app-exp (la rator bs) (map (lambda (x) (la x bs)) rands)))
             )))
       (get-pos
         (lambda (s lst)
           (if (eqv? s (car lst))
             0
             (+ 1 (get-pos s (cdr lst)))))))
      (cases program pgm
        (a-program (exp)
          (a-program (la exp '())))))))

(define eval-program
  (lambda (pgm)
    (cases program pgm
      (a-program (body)
        (eval-expression body (init-env))))))

(define eval-expression
  (lambda (exp env)
    (cases expression exp
      (lit-exp (datum) datum)
      (var-exp (id) (eopl:error 'eval-expression "~s is not lexival variable" id))
      (lexvar-exp (pos) (apply-env env pos))
      (primapp-exp (prim rands)
        (let ((args (eval-rands rands env)))
          (apply-primitive prim args)))
      (if-exp (test-exp true-exp false-exp)
        (if (true-value? (eval-expression test-exp env))
          (eval-expression true-exp env)
          (eval-expression false-exp env)))
      (let-exp (ids rands body)
        (let ((args (eval-rands rands env)))
          (eval-expression body (extend-env args env))))
      (proc-exp (ids body)
        (closure ids body env))
      (app-exp (rator rands)
        (let ((proc (eval-expression rator env))
              (args (eval-rands rands env)))
          (apply-procval proc args)))
      )))

(define eval-rands
  (lambda (rands env)
    (map (lambda (x) (eval-rand x env)) rands)))

(define eval-rand
  (lambda (rand env)
    (eval-expression rand env)))

(define apply-primitive
  (lambda (prim args)
    (cases primitive prim
      (add-prim () (+ (car args) (cadr args)))
      (subtract-prim () (- (car args) (cadr args)))
      (mult-prim () (* (car args) (cadr args)))
      (incr-prim () (+ (car args) 1))
      (decr-prim () (- (car args) 1))
      )))

(define apply-procval
  (lambda (proc args)
    (proc args)))

(define init-env
  (lambda () (empty-env)))

(define scanner-spec-3-8
  '((white-sp
      (whitespace) skip)
    (comment
      ("%" (arbno (not #\newline))) skip)
    (identifier
      (letter (arbno (or letter digit "?"))) symbol)
    (number
      (digit (arbno digit)) number)))

(define grammar-3-8
  '((program
      (expression)
      a-program)
    (expression
      (number)
      lit-exp)
    (expression
      (identifier)
      var-exp)
    (expression
      ("[" number "]")
      lexvar-exp)
    (expression
      (primitive "(" (separated-list expression ",") ")" )
      primapp-exp)
    (expression
      ("if" expression "then" expression "else" expression)
      if-exp)
    (expression
      ("let" (arbno identifier "=" expression) "in" expression)
      let-exp)
    (expression
      ("proc" "(" (separated-list identifier ",") ")" expression)
      proc-exp)
    (expression
      ("(" expression (arbno expression) ")")
      app-exp)
    (primitive ("+") add-prim)
    (primitive ("-") subtract-prim)
    (primitive ("*") mult-prim)
    (primitive ("add1") incr-prim)
    (primitive ("sub1") decr-prim)
    ))

(define scan&parse
  (sllgen:make-string-parser
    scanner-spec-3-8
    grammar-3-8))

(sllgen:make-define-datatypes scanner-spec-3-8 grammar-3-8)

(define run
  (lambda (string)
    (eval-program
      (lexical-address
      (scan&parse string)))))

(define read-eval-print
  (sllgen:make-rep-loop "-->" (lambda (x) (eval-program (lexical-address x)))
    (sllgen:make-stream-parser
      scanner-spec-3-8
      grammar-3-8)))